Technics — Wed, 18 Oct 2000 15:44:11 +0000

Thanks again.

Well im very stumped now. I tryed adding those to the script but dont know what im doing wrong because no matter what i get an internal server error. I'm no perl whizz as you can see.

Apply Common Sense

japhy — Wed, 18 Oct 2000 14:33:13 +0000

Ok, so you're getting a server error. When you used my code, did you:

* make a variable called $IP_FILE that holds the path to the file you want to edit?
* call the function as addIP($addr), where $addr is a scalar holding an IP address?
* make sure the web user can write to the IP address file?
* check the error log to see WHY the program died?

I suggest you include this line of code near the top of your program:

use CGI::Carp 'fatalsToBrowser';

Assuming you HAVE the CGI::Carp module, this will send fatal errors to your browser, instead of just being less-than-helpful.

Technics — Wed, 18 Oct 2000 14:25:30 +0000

Thanks guys for your help but both codes both cause internal server errors .

Ground Zero

japhy — Wed, 18 Oct 2000 14:20:35 +0000

I really think we need to start from scratch here. WHAT does the file holding the IP addresses look like? Is it just one IP address per line? Or is there more data?

Next, all you want to do is see whether or not the IP address is in the file, and if it is not, add it?

If I have these basic ideas down correctly, then I suggest you try the following code. I'm going to present in stages.

Code 1.0

sub addIP {
  my $to_add = shift;
  my $found = 0;
 
  # look for it in the file
  open FILE, $IP_FILE or die "can't open $IP_FILE: $!";
  while (<FILE>) {
    chomp;
    if ($_ eq $to_add) { $found = 1; last; }
  }
  close FILE;
 
  # add it to the file if it wasn't there
  if (not $found) {
    open FILE, ">> $IP_FILE" or die "can't append to $IP_FILE: $!";
    print FILE "$to_add\n";
    close FILE;
  }
}

This code saves us the trouble of reading through the entire file if the IP address is already in there, due to me calling last() if the IP address is found. This code can be made more efficient, though, by opening the file for reading AND writing:

Code 2.0

sub addIP {
  my $to_add = shift;
  my $found = 0;
 
  # look for it in the file
  open FILE, "+< $IP_FILE" or die "can't open $IP_FILE for read/write: $!";
  seek FILE, 0, 0;  # ensure we're at the beginning
  while (<FILE>) {
    chomp;
    if ($_ eq $to_add) { $found = 1; last; }
  }
 
  # add it if not found
  if (not $found) {
    print FILE "$to_add\n";
  }
  close FILE;
}

This is better, since we only open the file once, and it still works as before. I'm going to streamline things a bit, to make it look a bit cleaner:

Code 2.1

sub addIP {
  my $to_add = shift;
  my $found = 0;
 
  # look for it in the file
  open FILE, "+< $IP_FILE" or die "can't open $IP_FILE for read/write: $!";
  seek FILE, 0, 0;  # ensure we're at the beginning
  while (<FILE>) {
    chomp;
    last if $found = ($_ eq $to_add);  # XXX
  }
 
  # add it if not found
  print FILE "$to_add\n" if not $found;
 
  close FILE;
}

The line I marked with XXX is pretty nifty -- if $_ and $to_add are the same, then $_ eq $to_add is true, and returns 1. Otherwise, it's false, and returns ''. In turn, $found gets set to the value returned by that test, so if the test returns 1, $found is set to 1, and we can exit the block.

There's another thing I'd suggest adding, which is file locking. This is so that if two people run your program at once, you needn't worry about your file getting corrupted.

Code 3.0

use Fcntl 'LOCK_EX';  # import the LOCK_EX constant
 
sub addIP {
  my $to_add = shift;
  my $found = 0;
 
  # look for it in the file
  open FILE, "+< $IP_FILE" or die "can't open $IP_FILE for read/write: $!";
  flock FILE, LOCK_EX;  # lock this file
  seek FILE, 0, 0;  # ensure we're at the beginning
  while (<FILE>) {
    chomp;
    last if $found = ($_ eq $to_add);
  }
 
  # add it if not found
  print FILE "$to_add\n" if not $found;
 
  close FILE;
  # file gets unlocked automatically
}

And last, but not least, let's localize the filehandle, so we can get rid of the $found variable too, as well as have Perl close the filehandle for us:

Code 3.1

use Fcntl 'LOCK_EX';  # import the LOCK_EX constant
 
sub addIP {
  my $to_add = shift;
  local *FILE;  # localize the filehandle
 
  # look for it in the file
  open FILE, "+< $IP_FILE" or die "can't open $IP_FILE for read/write: $!";
  flock FILE, LOCK_EX;  # lock this file
  seek FILE, 0, 0;  # ensure we're at the beginning
  while (<FILE>) {
    chomp;
    return if $_ eq $to_add;  # return if found
  }
 
  # if we got here, it couldn't have been found
  print FILE "$to_add\n";
  # file gets unlocked automatically
}

Ok, that's all for now.

Orpheus — Wed, 18 Oct 2000 06:24:56 +0000

Ok, scratch that. It MIGHT work, i just noticed you didn't do a file to string right away, but it's best to be safe.

Orpheus — Wed, 18 Oct 2000 06:22:29 +0000

nope, that wont work

it will only do the first line of the file

try this

sub removeaddr {
local($/);
open (FILE, "$banfile");
$ThePage = join('|', <FILE>;
close (FILE);

$ThePage =~ /(.*)$input{'ipnumber'}|(.*)/;
$ThePage = $1 . $2;
$ThePage =~ s/\|/\n/g;

open(FILE, ">$banfile");
print FILE $ThePage;
close(FILE);
}
} 

Mark Hensler — Wed, 18 Oct 2000 03:39:09 +0000

I don't understand?

your saying that this won't work?

open (FILE, "$banfile");
$ThePage = join('|', <FILE>;
close (FILE);

$ThePage =~ s/\|/\n/g;
print $ThePage;

Try it... I've used it before and it's worked fine.

what does local(); do?
I've seen $_ but not $\ ... do you mean local($_);?

Orpheus — Wed, 18 Oct 2000 00:48:30 +0000

You can't push the entire contents of a file into a file into a string without saying local($\); first.

Just thought i'd point that out.

Mark Hensler — Tue, 17 Oct 2000 22:22:33 +0000

You want to make a script to remove IPs from the list?

I'll use the same variable for the IP and let you make a new subroutin to put it in...

sub removeaddr {

open (FILE, "$banfile");
$ThePage = join('|', <FILE>;
close (FILE);

$ThePage =~ /(.*)$input{'ipnumber'}|(.*)/;
$ThePage = $1 . $2;
$ThePage =~ s/\|/\n/g;

open(FILE, ">$banfile");
print FILE $ThePage;
close(FILE);
} #END unless

} #END sub

Logic:
1) replace "|" with newline characters
2) match the pattern [wild card] IP [wild card]
3) make $ThePage the first wild card and the second (thus, removing the IP)
4) put $ThePage back into the file

Technics — Tue, 17 Oct 2000 14:13:51 +0000

thanks it works.

Whats the command to edit a text file from a cgi script?. To also remove the banned ip from the list. Instead of logging into ftp and removing it.

Thank you for your help.